X-MAS Animation mit imc FAMOS

Animation 2019

This Seasonal graphic was drawn with imc FAMOS.

 

Download the sequence

 

The imc FAMOS sequence used to create the animation can be downloaded via the following button.

X-MAS-2019.seq

;*******************************************************************
;                    X-mas 2019
;*******************************************************************
;             We wish you a Merry Christmas 
;                          and
;                a happy new year 2020
;
;                imc Test & Measurement 
;*******************************************************************

 

;----------------------------------------------------------------
; const
;----------------------------------------------------------------
;----- View
imc:LineType_No = 0
imc:LineType_line = 1
imc:LineType_Dots = 3
imc:LineType_VertLine = 4
imc:LineType_Bar = 5
imc:LineType_Bar3d = 7
imc:LineType_Interpolation = 8

imc:Symbol_No = 0
imc:Symbol_Square = 1
imc:Symbol_circle = 2
imc:Symbol_Triangles_up = 3
imc:Symbol_Triangles_down = 4
imc:Symbol_diamond = 5
imc:Symbol_Plus = 6
imc:Symbol_x = 7
imc:Symbol_Dot = 8
imc:Symbol_HorizontalLine = 9
imc:Symbol_Triangles_Right = 10
imc:Symbol_Triangles_Left = 11
imc:Symbol_SandGlass = 12
imc:Symbol_SandGlass_1 = 13
imc:Symbol_Diamond_Filled = 14
imc:Symbol_Square_Filled = 5
imc:Symbol_Trinagle_Right_Filled = 16
imc:Symbol_Triangle_Left_Filled = 117
imc:Symbol_Triangle_Up_Filled = 18
imc:Symbol_Triangle_Down_Filles = 19
imc:Symbol_Square_Filled_Up = 20
imc:Symbol_Square_Filled_Down = 21
imc:Symbol_SandGlass_Filled = 22
imc:Symbol_SandGlass1_Filled = 23
imc:Symbol_Minus = 24

;----- color
imcColor:Sky = RGB( 0, 8, 76)
imcColor:Earth = RGB( 0, 74, 192)
imcColor:Snow = RGB( 255,255, 255)
;imcColor:Snow = RGB( 176, 192, 255)
imcColor:Tree = RGB( 0, 0, 255)
imcColor:TreeLigth = RGB( 0, 0, 255)
imcColor:imc = RGB( 218, 0, 70)
imcColor:Star_M = RGB( 175, 192, 255)
imcColor:Star_S = RGB( 175, 255, 255)
imcColor:Nr1 = RGB( 0, 255, 255)
imcColor:Nr2 =RGB( 0, 0, 96)

imcColor:Nr1 = RGB( 0, 255, 255)
imcColor:Nr2 =RGB( 0, 0, 96)

Canvas:x1 = -2
Canvas:x2 =  7
Canvas:y1 =  0
Canvas:y2 = 20
Canvas:Width = Canvas:x2 - Canvas:X1
Canvas:Hight = Canvas:Y2 - Canvas:Y1


;----------------------------------------------------------------
; some Measurement Signals
;----------------------------------------------------------------

;----- Landscape
Winter:Sky     = Rampe( Canvas:x1, 0.01, Canvas:Width*100)*0 + Canvas:Y2
_t = Rampe( Canvas:x1, 0.01, Canvas:Width*100)
_t = _t/max(_t)
_t = _t*-1 +1
_t =_t * 15
Winter:Sky     = _t;
Winter:Sky_Color     = _t;

;----- Nordlichter - oder doch Berge?
_t = Rampe( Canvas:x1, 0.01, Canvas:Width*100)
_t = _t / Max(_t) * 2 * Pi
_t = sin( _t) + _t
_t = _t * 3.5
_t = _t + 4
Winter:Licht1 = _t
_t = Rampe( Canvas:x1, 0.01, Canvas:Width*100)
_t = _t / Max(_t) * 2 *Pi
_t = sin( _t) +1 ; + _t
_t = _t*10
Winter:Licht1_Color = _t

_t = Rampe( Canvas:x1, 0.01, Canvas:Width*100)
_t = _t / Max(_t) * 2 * Pi
_t = sin( _t) + _t
_t = _t * 3.5;2.5
_t = _t + 4
Winter:Licht2 = _t
_t = Rampe( Canvas:x1, 0.01, Canvas:Width*100)
_t = _t / Max(_t) * 2 *Pi -2
_t = sin( _t) +1; + _t
_t = _t*10
Winter:Licht2_Color = _t;Winter:Sky_Color + 10;

_t = Rampe( Canvas:x1, 0.01, Canvas:Width*100)
_t = _t / Max(_t) * 2 * Pi
_t = sin( _t) + _t
_t = _t * 1.5
_t = _t + 4
Winter:Licht3 = _t

;----- Erde/Horizont
_t = Rampe(0, 0.1, Canvas:Width * 10)
_t = 1- _t / max( _t); * 4
Winter:Earth = _t * 4
Winter:Earth_Color= _t*20

_t = Rampe(Canvas:x1, 0.1, Canvas:Width * 10)
Winter:Horizont = _t*0 + 4

;----- Tree
_t = Ramp( 0.1, 0.1, 1000)
_a = _t/max(_t) * 10
_y = sin( _t) + _a
_y = _y + 2

_a = (_t/max(_t)) ^ -0.001 - 1
_a = 10 / max(_a) * _a
_x = cos( _t) * (_a)
_x = _x / 2
_x = _x - min( _x) + 3

Winter:Tree = xyVon( _x, _y)
_t = Rampe( 0, 0.1, 1000)
_t = _t / max(_t)
_t = 1- _t
_t = _t * 15

_t = Rampe( 0, 0.1, 1000)
_t = cos( _t)*15
Winter:Tree_Color = _t

Winter:Star = XYVon( 5.5, 12.8)
Winter:Star1 = XYVon( 5.5, 12.8)

;----- Lichter
_cnt = 20
_x = Rampe( 0, Max( _t) / _cnt, _cnt)
_y = Wert( Winter:Tree.y, _x)
_x = Wert( Winter:Tree.x, _x)
Winter:Dot = xyVon( _x, _y)

;----- Hintergrund
Winter:Back = xyVon( Binde( -5, 10), Binde( 11, 11))

;----- Sterne
_t = random( 150, 1, 0, 0, 0 )*6 + 2
_t = xDel( _t, 0.1)
_t = xOff( _t, -5)
Winter:Stars_S = _t

_t = random( 150, 1, 0, 0, 0 )*6+2;*10 + 2
_t = xDel( _t, 0.1)
_t = xOff( _t, -5)
Winter:Stars_M = _t

;----- Caption
Ein_Frohes_Fest_2019 = Leer

;----------------------------------------------------------------
; color
;----------------------------------------------------------------
SetColor( Winter:Stars_S,        imcColor:Star_S)
SetColor( Winter:Stars_M,        imcColor:Star_M)

SetColor( Winter:Earth,            imcColor:Earth)
SetColor( Winter:Horizont,        imccolor:imc)
SetColor( Winter:Sky,            imccolor:sky)
SetColor( Winter:Licht2,        imccolor:sky)
SetColor( Winter:Licht3,        imccolor:sky)
;SetColor( Winter:StarLite,        imccolor:imc)

SetColor( Winter:Star,        imccolor:imc)
SetColor( Winter:Star1,        imccolor:imc)

;----------------------------------------------------------------
; Painting
;----------------------------------------------------------------

 

;----- Vordergrund

WinterTime = empty
CwNewWindow( WinterTime, "show")

CwDisplaySet("legend.display",2)        ; Legende.Off

CwDisplaySet("color palette", 1)        ; Farbpalette.On
CwDisplaySet("3D.represent", 2);
CwDisplaySet("3D.color pattern", 1)        ; 2 Farben
CwDisplaySet("3d.colors.number", 100)
CwDisplaySet("3D.color.fix1", imcColor:Nr1)
CwDisplaySet("3d.color.fix2", imcColor:Nr2)
CwSelectByIndex("z-axis", 1)

CwAxisSet( "Range", 4)    ; fester Range
CwAxisSet( "min", -5)        ; 0..6
CwAxisSet( "max", 15)
CwSelectByIndex("y-axis", 1)
CwAxisSet( "Range", 4)    ; fester Range
CwAxisSet( "min", 0)        ; 0..6
CwAxisSet( "max", 22)
CwSelectByIndex("x-axis", 1)
CwAxisSet( "Range", 4)    ; fester Range
CwAxisSet( "min", -2)        ; 0..6
CwAxisSet( "max", 7)

CwDisplaySet("win.dx", 800)
CwDisplaySet("win.dy", 500)
CwDisplaySet("win.x", 0)
CwDisplaySet("win.y", 0)

;----- Messdaten - die Basis
CwNewChannel( "first line", Winter:Sky)
CwNewChannel( "append line", Winter:Sky_Color)
CwNewChannel( "first line", Winter:Stars_S)
CwNewChannel( "first line", Winter:Stars_M)
CwNewChannel( "first line", Winter:Licht1)
CwNewChannel( "append line", Winter:Licht1_Color)
CwNewChannel( "first line", Winter:Licht2)
CwNewChannel( "append line", Winter:Licht2_Color)
CwNewChannel( "first line", Winter:Licht3)
CwNewChannel( "first line", Winter:Earth)
CwNewChannel( "append line", Winter:Earth_Color)
CwNewChannel( "first line", Winter:Horizont)
CwNewChannel( "first line", Winter:Tree)
CwNewChannel( "append line", Winter:Tree_Color)    ; Color
CwNewChannel( "first line", Winter:Star)
CwNewChannel( "first line", Winter:Star1)
CwNewChannel( "first line", Ein_Frohes_Fest_2019)

;----- Landscape
CwSelectByChannel("line", Winter:Sky)
CwLineSet( "type", imc:LineType_no)
CwLineSet( "symbol", imc:Symbol_HorizontalLine)
CwLineSet( "symbolsize.screen", 1.5)
CwLineSet( "Width.screen", 6)
CwSelectByChannel("data", Winter:Sky_Color)            ; Select Channel
CwDataSet( "function", 1)                                    ; Channel = Farbe

CwSelectByChannel("line", Winter:Stars_S)
CwLineSet( "type", imc:LineType_No)
CwLineSet( "symbol", imc:Symbol_Dot)
CwLineSet( "symbolsize.screen", 1)

CwSelectByChannel("line", Winter:Stars_M)
CwLineSet( "type", imc:LineType_No)
CwLineSet( "symbol", imc:Symbol_Dot)
CwLineSet( "symbolsize.screen", 1.5)

CwSelectByChannel("line", Winter:Licht1)
CwLineSet( "type", imc:LineType_Bar)
CwLineSet( "Width.screen", 6)
CwSelectByChannel("data", Winter:Licht1_Color)        ; Select Channel
CwDataSet( "function", 1)                                    ; Channel = Farbe

CwSelectByChannel("line", Winter:Licht2)
CwLineSet( "type", imc:LineType_Bar)
CwLineSet( "Width.screen", 6)
CwSelectByChannel("data", Winter:Licht2_Color)            ; Select Channel
CwDataSet( "function", 1)                                    ; Channel = Farbe

CwSelectByChannel("line", Winter:Licht3)
CwLineSet( "type", imc:LineType_Bar)
CwLineSet( "Width.screen", 6)

CwSelectByChannel("line", Winter:Earth)
CwLineSet( "type", imc:LineType_No)
CwLineSet( "symbol", imc:Symbol_HorizontalLine); hooriz. linie
CwLineSet( "Width.screen", -1)

CwSelectByChannel("data", Winter:Earth_Color)            ; Select Channel
CwDataSet( "function", 1)    

CwSelectByChannel("line", Winter:Horizont)
CwLineSet( "Width.screen", 1.5)

CwSelectByChannel("line", Winter:Tree)
CwLineSet( "Width.screen", 1)
CwLineSet( "symbol", imc:Symbol_Dot)

CwSelectByChannel("data", Winter:Tree_Color)    ; Select Channel
CwDataSet( "function", 1)                                    ; Channel = Farbe

CwSelectByChannel("line", Winter:Star)
CwLineSet( "Width.screen", 1)
CwLineSet( "symbol", imc:Symbol_Plus)
CwLineSet( "symbolsize.screen", 5)

CwSelectByChannel("line", Winter:Star1)
CwLineSet( "Width.screen", 1)
CwLineSet( "symbol", imc:Symbol_x)
CwLineSet( "symbolsize.screen", 4)

;----- Canvas ausschneidenn
CwSelectByIndex("y-axis", 1)
CwAxisSet( "Range", 4)    ; fester Range
CwAxisSet( "min", Canvas:Y1)        ; 0..6
CwAxisSet( "max", Canvas:Y2)
CwSelectByIndex("x-axis", 1)
CwAxisSet( "Range", 4)    ; fester Range
CwAxisSet( "min", Canvas:X1)        ; 0..6
CwAxisSet( "max", Canvas:X2)

;----------------------------------------------------------------
; color
;----------------------------------------------------------------
SetColor( Winter:Stars_S,        imcColor:Star_S)
SetColor( Winter:Stars_M,        imcColor:Star_M)

SetColor( Winter:Earth,            imcColor:Earth)
SetColor( Winter:Horizont,        imccolor:imc)
SetColor( Winter:Sky,            imccolor:sky)
SetColor( Winter:Licht2,        imccolor:sky)
SetColor( Winter:Licht3,        imccolor:sky)
;SetColor( Winter:StarLite,        imccolor:imc)

SetColor( Winter:Star,        imccolor:imc)
SetColor( Winter:Star1,        imccolor:imc)


;----------------------------------------------------------------
; Clean up
;----------------------------------------------------------------
Del _*

;----------------------------------------------------------------
; Animation
;----------------------------------------------------------------
While 1
    Winter:Licht2_Color=Winter:Licht2_Color-2
    Winter:Tree_Color=Winter:Tree_Color-1
    Winter:Licht2_Color=Winter:Licht2_Color-2
    Winter:Tree_Color=Winter:Tree_Color-1
    Winter:Licht2_Color=Winter:Licht2_Color-2
    Winter:Tree_Color=Winter:Tree_Color-1
    Winter:Licht2_Color=Winter:Licht2_Color-2
    Winter:Tree_Color=Winter:Tree_Color-1
    Winter:Licht2_Color=Winter:Licht2_Color-2
    Winter:Tree_Color=Winter:Tree_Color-1
    
    Winter:Licht2_Color=Winter:Licht2_Color+2
    Winter:Tree_Color=Winter:Tree_Color+1
    Winter:Licht2_Color=Winter:Licht2_Color+2
    Winter:Tree_Color=Winter:Tree_Color+1
    Winter:Licht2_Color=Winter:Licht2_Color+2
    Winter:Tree_Color=Winter:Tree_Color+1
    Winter:Licht2_Color=Winter:Licht2_Color+2
    Winter:Tree_Color=Winter:Tree_Color+1
    Winter:Licht2_Color=Winter:Licht2_Color+2
    Winter:Tree_Color=Winter:Tree_Color+1
End

 

imc Test & Measurement is an Axiometrix Solutions company.

Top